Formula generica
=INT(end-start)&" days "&TEXT(end-start,"h"" hrs ""m"" mins """)
Sommario
Per calcolare e visualizzare giorni, ore e minuti tra due date, è possibile utilizzare la funzione TESTO con un piccolo aiuto dalla funzione INT. Nell'esempio mostrato, la formula in D5 è:
=INT(C5-B5)&" days "&TEXT(C5-B5,"h"" hrs ""m"" mins """)
Spiegazione
La maggior parte del lavoro in questa formula viene svolto dalla funzione TESTO, che applica un formato numerico personalizzato per ore e minuti a un valore creato sottraendo la data di inizio dalla data di fine.
TEXT(C5-B5,"h"" hrs ""m"" mins """)
Questo è un esempio di incorporamento del testo in un formato numerico personalizzato e questo testo deve essere racchiuso tra due virgolette aggiuntive. Senza le virgolette doppie extra, il formato del testo personalizzato ha questo aspetto:
h "hrs" m "min"
Il valore per i giorni viene calcolato con la funzione INT, che restituisce semplicemente la parte intera della data di fine meno la data di inizio:
INT(C5-B5) // get day value
Nota: sebbene sia possibile utilizzare "d" in un formato numerico personalizzato per i giorni, il valore verrà reimpostato su zero quando i giorni sono maggiori di 31.
Includi secondi
Per includere i secondi, puoi estendere il formato numerico personalizzato in questo modo:
=INT(C5-B5)&" days "&TEXT(C5-B5,"h"" hrs ""m"" mins ""s"" secs""")
Giorni, ore e minuti totali tra le date
Per ottenere il totale di giorni, ore e minuti tra un insieme di date di inizio e di fine, puoi adattare la formula utilizzando SUMPRODUCT in questo modo:
=INT(SUMPRODUCT(ends-starts))&" days "&TEXT(SUMPRODUCT(ends-starts),"h"" hrs ""m"" mins """)
dove "finisce" rappresenta l'intervallo di date di fine e "inizio" rappresenta l'intervallo di date di inizio. Nell'esempio mostrato, D11 contiene questa formula:
=INT(SUMPRODUCT(C5:C9-B5:B9))&" days "&TEXT(SUMPRODUCT(C5:C9-B5:B9),"h"" hrs ""m"" mins """)
