Formula Excel: XLOOKUP con più criteri -

Formula generica

=XLOOKUP(val1&val2&val3,rng1&rng2&rng3,results)

Sommario

Per utilizzare XLOOKUP con più criteri, puoi concatenare valori di ricerca e matrici di ricerca direttamente nella formula. Nell'esempio mostrato, la formula in H8 è:

=XLOOKUP(H5&H6&H7,B5:B14&C5:C14&D5:D14,E5:E14)

XLOOKUP restituisce $ 17,00, il prezzo di una t-shirt rossa grande.

Nota: XLOOKUP può gestire gli array in modo nativo; non è necessario entrare con CTRL + MAIUSC + INVIO.

Spiegazione

Uno dei bei vantaggi di XLOOKUP rispetto a CERCA.VERT è che XLOOKUP può funzionare direttamente con gli array, invece di richiedere intervalli su un foglio di lavoro. Ciò rende possibile assemblare array nella formula e inserirli nella funzione.

Lavorando un argomento alla volta, il valore di ricerca viene creato unendo H5, H6 e H7 utilizzando la concatenazione:

=XLOOKUP(H5&H6&H7

Ciò si traduce nella stringa "T-shirtLargeRed".

L'array di ricerca viene creato in modo simile, tranne che ora stiamo unendo intervalli:

=XLOOKUP(H5&H6&H7,B5:B14&C5:C14&D5:D14

L'array di ritorno viene fornito come un intervallo normale :, E5: E14:

=XLOOKUP(H5&H6&H7,B5:B14&C5:C14&D5:D14,E5:E14

In sostanza, stiamo cercando il valore di ricerca "T-shirtLargeRed" in dati come questo:

lookup_array array_risultato
T-shirtSmallRed 15
T-shirtMediumBlue 16
T-shirtLargeRed 17
Felpa con cappuccio SmallGray 28
Felpa con cappuccioMediumBlue 29
Felpa con cappuccio LargeBlack 30
HatMediumBlack 25
HatMediumGray 26
HatLargeRed 24
Maglietta LargeBlue 16

Per impostazione predefinita, la modalità di corrispondenza è esatta e la modalità di ricerca è la prima corrispondenza, quindi XLOOKUP restituisce $ 17,00.

Con logica booleana

Sebbene la sintassi spiegata sopra funzioni bene per la semplice corrispondenza "uguale a", puoi anche utilizzare la logica booleana per costruire una formula come questa:

=XLOOKUP(1,(B5:B14=H5)*(C5:C14=H6)*(D5:D14=H7),E5:E14)

Si tratta di un approccio più flessibile perché la sintassi può essere regolata per utilizzare altri operatori logici e altre funzioni secondo necessità per ricerche più complesse.

Articoli interessanti...