In questo video vedremo come utilizzare la funzione SCEGLI.
Diamo un'occhiata a tre esempi.
Ecco alcuni articoli elencati con un codice colore numerico. Vogliamo portare questi nomi nella colonna D.
Ora, poiché ho già la tabella già qui, potrei semplicemente usare CERCA.VERT e fare riferimento alla tabella. Ottengo il valore di ricerca dalla colonna C, la tabella è nell'intervallo H5: I7, bloccato con F4, la colonna è 2 e devo usare FALSE per forzare una corrispondenza esatta.
=VLOOKUP(C5,$H$5:$I$7,2,FALSE)
Quando copio la formula, abbiamo i nostri nomi di colore.
Funziona bene, ma possiamo fare la stessa cosa con SCEGLI senza tavolo.
Con SCEGLI, il primo argomento è un indice e gli argomenti rimanenti sono scelte. Se utilizzo 2 come indice e fornisco "rosso", "verde" e "blu" come valori, SCEGLI restituisce "verde", poiché il verde è il secondo elemento.
=CHOOSE(2,"red", "green", "blue")
Poiché abbiamo già codici numerici nella colonna C, posso semplicemente sostituire l'indice hardcoded con un riferimento di cella e copiare la formula verso il basso.
=CHOOSE(C5,"red", "green", "blue")
Otteniamo lo stesso risultato di CERCA.VERT e non abbiamo affatto bisogno di questa tabella.
Nel prossimo esempio, traduciamo una scala di valutazione a 4 punti in valori di testo, dove 1 è scarso e 4 è eccellente.
Nella colonna D, abbiamo una classica formula IF annidata
Posso sostituire questa formula con una formula più semplice basata su SCEGLI.
=CHOOSE(C5,"Poor","OK","Good","Excellent")
Quando copio la formula, otteniamo gli stessi risultati.
SCEGLI funziona anche con i riferimenti di cella. Se voglio, posso prendere direttamente i valori dalla tabella e usarli all'interno di SCEGLI.
=CHOOSE(C5,$I$5,$I$6,$I$7,$I$8)
Ora la tabella funziona come una chiave dinamica. Se cambio un valore nella tabella, si riflette nella formula.
In questo ultimo esempio, useremo SCEGLI per assegnare un trimestre a qualsiasi data.
Per prima cosa userò la funzione MESE per estrarre un numero compreso tra 1 e 12 da ogni data.
=MONTH(B5)
Successivamente, inserirò semplicemente la funzione MESE all'interno di SCEGLI e utilizzerò MESE per generare l'indice. Devo quindi fornire 12 valori, uno per ogni mese.
=CHOOSE(MONTH(B5),1,1,1,2,2,2,3,3,3,4,4,4)
Il risultato è un numero che corrisponde a un quarto. Come tocco finale, posso usare la concatenazione per aggiungere una "Q" prima del numero.
="Q"&CHOOSE(MONTH(B5),1,1,1,2,2,2,3,3,3,4,4,4)
La cosa interessante di questa particolare soluzione è che l'ordine delle scelte può essere facilmente modificato per adattarsi a trimestri fiscali con mesi di inizio diversi.
=CHOOSE(MONTH(B5),1,1,1,2,2,2,3,3,3,4,4,4) // Jan start =CHOOSE(MONTH(B5),4,4,4,1,1,1,2,2,2,3,3,3) // Apr start =CHOOSE(MONTH(B5),3,3,3,4,4,4,1,1,1,2,2,2) // Jul start =CHOOSE(MONTH(B5),2,2,2,3,3,3,4,4,4,1,1,1) // Oct start
Quindi è così.
La funzione SCEGLI esegue semplici ricerche e talvolta può sostituire CERCA.VERT, INDICE e CONFRONTA più complicati o IF annidati.
La prossima volta che dovrai mappare numeri interi in valori specifici, non dimenticare la funzione SCEGLI.
Corso
Formula di baseScorciatoie correlate
Alterna i riferimenti assoluti e relativi F4
⌘
+ T
Elimina colonne Ctrl
+ -
⌘
+ -
Estendi la selezione all'ultima cella verso il basso Ctrl
+ Shift
+ ↓
⌃
+ ⇧
+ ↓
Completa la voce e rimani nella stessa cella Ctrl
+ Enter
⌃
+ Return
Seleziona fogli di lavoro non adiacenti Ctrl
+ Click
⌘
+ Click
Inserisci gli stessi dati in più celle Ctrl
+ Enter
⌃
+ Return
Seleziona solo cella attiva Shift
+ Backspace
⇧
+ Delete