Formula di Excel: XLOOKUP corrispondenza esatta a due vie -

Formula generica

=XLOOKUP(A1,months,XLOOKUP(A2,names,data))

Sommario

Per eseguire una ricerca in due con la funzione XLOOKUP (un XLOOKUP doppio), è possibile annidare un XLOOKUP all'interno di un altro. Nell'esempio mostrato, la formula in H6 è:

=XLOOKUP(H5,months,XLOOKUP(H4,names,data))

dove mesi (C4: E4), nomi (B5: B13) e dati (C5: E13) sono intervalli denominati.

Spiegazione

Una delle caratteristiche di XLOOKUP è la possibilità di cercare e restituire un'intera riga o colonna. Questa funzione può essere utilizzata per annidare un XLOOKUP all'interno di un altro per eseguire una ricerca bidirezionale. XLOOKUP interno restituisce un risultato al XLOOKUP esterno, che restituisce un risultato finale.

Nota: XLOOKUP esegue una corrispondenza esatta per impostazione predefinita, quindi la modalità di corrispondenza non è impostata.

Lavorando dall'interno verso l'esterno, XLOOKUP interno viene utilizzato per recuperare tutti i dati per "Frantz":

XLOOKUP(H4,names,data)

XLOOKUP trova "Frantz" nei nomi degli intervalli denominati (B5: B13). Frantz appare nella quinta riga, quindi XLOOKUP restituisce la quinta riga di dati (C5: E13). Il risultato è un array che rappresenta una singola riga di dati per Frantz, contenente 3 mesi di vendite:

(10699,5194,10525) // data for Frantz

Questo array viene restituito direttamente al XLOOKUP esterno come return_array:

=XLOOKUP(H5,months,(10699,5194,10525))

XLOOKUP esterno trova il valore in H5 ("Mar") all'interno dell'intervallo denominato mesi (C4: E4). Il valore "Mar" viene visualizzato come terzo articolo, quindi XLOOKUP restituisce il terzo articolo dai dati di vendita, il valore 10525.

Senza intervalli denominati

Gli intervalli denominati utilizzati in questo esempio sono solo di leggibilità. Senza intervalli denominati, la formula è:

=XLOOKUP(H5,C4:E4,XLOOKUP(H4,B5:B13,C5:E13))

INDICE e MATCH

Questo esempio può essere risolto con INDEX e MATCH in questo modo:

=INDEX(C5:E13,MATCH(H4,B5:B13,0),MATCH(H5,C4:E4,0))

INDICE e CONFRONTA è una buona soluzione a questo problema e probabilmente più facile da capire per la maggior parte delle persone. Tuttavia, la versione XLOOKUP mostra la potenza e la flessibilità di XLOOKUP.

Articoli interessanti...