Come utilizzare la funzione CERCA.VERT di Excel -

Sommario

CERCA.VERT è una funzione di Excel per cercare i dati in una tabella organizzata verticalmente. CERCA.VERT supporta la corrispondenza approssimativa ed esatta e i caratteri jolly (*?) Per le corrispondenze parziali. I valori di ricerca devono essere visualizzati nella prima colonna della tabella passata a CERCA.VERT.

Scopo

Cerca un valore in una tabella facendo corrispondere la prima colonna

Valore di ritorno

Il valore corrispondente da una tabella.

Sintassi

= CERCA.VERT (valore, tabella, col_index, (range_lookup))

argomenti

valore - Il valore da cercare nella prima colonna di una tabella.
table - La tabella da cui recuperare un valore.
col_index - La colonna nella tabella da cui recuperare un valore.
range_lookup - (opzionale) TRUE = corrispondenza approssimativa (impostazione predefinita). FALSO = corrispondenza esatta.

Versione

Excel 2003

Note sull'utilizzo

CERCA.VERT è una funzione di Excel per ottenere dati da una tabella organizzata verticalmente. I valori di ricerca devono essere visualizzati nella prima colonna della tabella passata a CERCA.VERT. CERCA.VERT supporta la corrispondenza approssimativa ed esatta e i caratteri jolly (*?) Per le corrispondenze parziali.

V sta per verticale

Lo scopo di CERCA.VERT è ottenere informazioni da una tabella organizzata in questo modo:

Utilizzando il numero dell'ordine nella colonna B come valore di ricerca, CERCA.VERT può ottenere l'ID cliente, l'importo, il nome e lo stato per qualsiasi ordine. Ad esempio, per ottenere il nome del cliente per l'ordine 1004, la formula è:

=VLOOKUP(1004,B5:F9,4,FALSE) // returns "Sue Martin"

Per i dati orizzontali, è possibile utilizzare CERCA.ORIZZ, INDICE e CONFRONTA o CERCA.ORIZZ.

CERCA.VERT si basa sui numeri di colonna

Quando utilizzi CERCA.VERT, immagina che ogni colonna della tabella sia numerata, a partire da sinistra. Per ottenere un valore da una particolare colonna, fornire il numero appropriato come "indice di colonna". Ad esempio, l'indice della colonna per recuperare il nome di seguito è 2:

Il cognome e l'email possono essere recuperati con le colonne 3 e 4:

=VLOOKUP(H3,B4:E13,2,FALSE) // first name =VLOOKUP(H3,B4:E13,3,FALSE) // last name =VLOOKUP(H3,B4:E13,4,FALSE) // email address

CERCA.VERT sembra giusto

CERCA.VERT può guardare solo a destra. I dati che desideri recuperare (valori dei risultati) possono essere visualizzati in qualsiasi colonna a destra dei valori di ricerca:

Se è necessario cercare i valori a sinistra, vedere INDICE e CONFRONTA o XLOOKUP.

Corrispondenza esatta e approssimativa

CERCA.VERT ha due modalità di corrispondenza, esatta e approssimativa. Il nome dell'argomento che controlla la corrispondenza è " range_lookup ". Questo è un nome confuso, perché sembra avere qualcosa a che fare con intervalli di celle come A1: A10. In realtà, la parola "intervallo" in questo caso si riferisce a "intervallo di valori": quando range_lookup è TRUE, CERCA.VERT corrisponderà a un intervallo di valori anziché a un valore esatto. Un buon esempio di ciò è l'utilizzo di CERCA.VERT per calcolare i voti.

È importante capire che range_lookup è impostato su TRUE, il che significa che CERCA.VERT utilizzerà la corrispondenza approssimativa per impostazione predefinita, il che può essere pericoloso. Imposta range_lookup su FALSE per forzare la corrispondenza esatta:

=VLOOKUP(value, table, col_index) // approximate match (default) =VLOOKUP(value, table, col_index, TRUE) // approximate match =VLOOKUP(value, table, col_index, FALSE) // exact match

Nota: puoi anche fornire zero (0) invece di FALSO per una corrispondenza esatta.

Corrispondenza esatta

Nella maggior parte dei casi, probabilmente vorrai utilizzare CERCA.VERT in modalità di corrispondenza esatta. Ciò ha senso quando si dispone di una chiave univoca da utilizzare come valore di ricerca, ad esempio il titolo del film in questi dati:

La formula in H6 per trovare l' anno , basata su una corrispondenza esatta del titolo del film, è:

=VLOOKUP(H4,B5:E9,2,FALSE) // FALSE = exact match

Corrispondenza approssimativa

In cases when you want the best match , not necessarily an exact match , you'll want to use approximate mode. For example, below we want to look up a commission rate in the table G5:H10. The lookup values come from column C. In this example, we need to use VLOOKUP in approximate match mode, because in most cases an exact match will never be found. The VLOOKUP formula in D5 is configured to perform an approximate match by setting the last argument to TRUE:

=VLOOKUP(C5,$G$5:$H$10,2,TRUE) // TRUE = approximate match

VLOOKUP will scan values in column G for the lookup value. If an exact match is found, VLOOKUP will use it. If not, VLOOKUP will "step back" and match the previous row.

Note: data must be sorted in ascending order by lookup value when you use approximate match mode with VLOOKUP.

First match

In the case of duplicate values, VLOOKUP will find the first match when the match mode is exact. In screen below, VLOOKUP is configured to find the price for the color "Green". There are three entries with the color Green, and VLOOKUP returns the price for the first entry, $17. The formula in cell F5 is:

=VLOOKUP(E5,B5:C11,2,FALSE) // returns 17

Wildcard match

The VLOOKUP function supports wildcards, which makes it possible to perform a partial match on a lookup value. For instance, you can use VLOOKUP to retrieve values from a table after typing in only part of a lookup value. To use wildcards with VLOOKUP, you must specify exact match mode by providing FALSE or 0 for the last argument, range_lookup . The formula in H7 retrieves the first name, "Michael", after typing "Aya" into cell H4:

=VLOOKUP($H$4&"*",$B$5:$E$104,2,FALSE)

Read a more detailed explanation here.

Two-way lookup

Inside the VLOOKUP function, the column index argument is normally hard-coded as a static number. However, you can also create a dynamic column index by using the MATCH function to locate the right column. This technique allows you to create a dynamic two-way lookup, matching on both rows and columns. In the screen below, VLOOKUP is configured to perform a lookup based on Name and Month. The formula in H6 is:

=VLOOKUP(H4,B5:E13,MATCH(H5,B4:E4,0),0)

For more details, see this example.

Note: In general, INDEX and MATCH is a more flexible way to perform two-way lookups.

Multiple criteria

The VLOOKUP function does not handle multiple criteria natively. However, you can use a helper column to join multiple fields together, and use these fields like multiple criteria inside VLOOKUP. In the example below, Column B is a helper column that concatenates first and last names together with this formula:

=C5&D5 // helper column

VLOOKUP is configured to do the the same thing to create a lookup value. The formula in H6 is:

=VLOOKUP(H4&H5,B5:E13,4,0)

For details, see this example.

Note: INDEX and MATCH and XLOOKUP are more robust ways to handle lookups based on multiple criteria.

VLOOKUP and #N/A errors

If you use VLOOKUP you will inevitably run into the #N/A error. The #N/A error just means "not found". For example, in the screen below, the lookup value "Toy Story 2" does not exist in the lookup table, and all three VLOOKUP formulas return #N/A:

One way to "trap" the NA error is to use the IFNA function like this:

The formula in H6 is:

=IFNA(VLOOKUP(H4,B5:E9,2,FALSE),"Not found")

The message can be customized as desired. To return nothing (i.e. to display a blank result) when VLOOKUP returns #N/A you can use an empty string like this:

=IFNA(VLOOKUP(H4,B5:E9,2,FALSE),"") // no message

The #N/A error is useful because it tells you something is wrong. In practice, there are many reasons why you might see this error, including:

The lookup value does not exist in the table
The lookup value is misspelled, or contains extra space
Match mode is exact, but should be approximate
The table range is not entered correctly
You are copying VLOOKUP, and the table reference is not locked

More about VLOOKUP

More VLOOKUP examples
VLOOKUP videos
23 tips for using VLOOKUP

Other notes

Range_lookup controls whether value needs to match exactly or not. The default is TRUE = allow non-exact match.
Set range_lookup to FALSE to require an exact match and TRUE to allow a non-exact match .
If range_lookup is TRUE (the default setting), a non-exact match will cause the VLOOKUP function to match the nearest value in the table that is still less than value .
When range_lookup is omitted, the VLOOKUP function will allow a non-exact match, but it will use an exact match if one exists.
If range_lookup is TRUE (the default setting) make sure that lookup values in the first row of the table are sorted in ascending order. Otherwise, VLOOKUP may return an incorrect or unexpected value.
If range_lookup is FALSE (require exact match), values in the first column of table do not need to be sorted.