Sommario
Per calcolare l'imposta sul reddito totale in base a più scaglioni fiscali, è possibile utilizzare CERCA.VERT e una tabella dei tassi strutturata come mostrato nell'esempio. La formula in G5 è:
=VLOOKUP(inc,rates,3,1)+(inc-VLOOKUP(inc,rates,1,1))*VLOOKUP(inc,rates,2,1)
dove "inc" (G4) e "tassi" (B5: D11) sono denominati intervalli e la colonna D è una colonna ausiliaria che calcola l'imposta accumulata totale in ciascuna fascia.
Sfondo e contesto
Il sistema fiscale statunitense è "progressivo", il che significa che le persone con un reddito imponibile più elevato pagano un'aliquota fiscale federale più elevata. Le tariffe sono valutate tra parentesi definite da una soglia superiore e inferiore. L'importo del reddito che rientra in una data fascia è tassato all'aliquota corrispondente per quella fascia. Con l'aumento del reddito imponibile, il reddito viene tassato su più fasce di imposta. Molti contribuenti pagano quindi diverse aliquote.
Nell'esempio mostrato, le fasce e le aliquote fiscali sono per i single filer negli Stati Uniti per l'anno fiscale 2019. La tabella seguente mostra i calcoli manuali per un reddito imponibile di $ 50.000:
| Staffa | Calcolo | Imposta |
|---|---|---|
| 10% | ($ 9.700 - $ 0) x 10% | $ 970,00 |
| 12% | ($ 39.475 - $ 9.700) x 12% | $ 3.573,00 |
| 22% | ($ 50.000- $ 39.475) x 22% | $ 2.315,50 |
| 24% | N / A | $ 0,00 |
| 32% | N / A | $ 0,00 |
| 35% | N / A | $ 0,00 |
| 37% | N / A | $ 0,00 |
L'imposta totale è quindi di $ 6,858,50. (visualizzato come 6,859 nell'esempio mostrato).
Note di installazione
1. Questa formula dipende dalla funzione CERCA.VERT in "modalità di corrispondenza approssimativa". In modalità di corrispondenza approssimativa, CERCA.VERT esegue la scansione dei valori di ricerca in una tabella (che deve essere ordinata in ordine crescente) finché non viene trovato un valore più alto. Quindi "tornerà indietro" e restituirà un valore dalla riga precedente. In caso di corrispondenza esatta, CERCA.VERT restituirà i risultati dalla riga corrispondente.
2. Affinché CERCA.VERT possa recuperare gli importi fiscali cumulativi effettivi, questi sono stati aggiunti alla tabella come colonna di supporto nella colonna D. La formula in D6, copiata verso il basso, è:
=((B6-B5)*C5)+D5
Ad ogni riga, questa formula applica il tasso dalla riga sopra al reddito in quella fascia.
3. Per la leggibilità, sono definiti i seguenti intervalli denominati: "inc" (G4) e "rate" (B5: D11).
Spiegazione
In G5, il primo CERCA.VERT è configurato per recuperare l'imposta cumulativa all'aliquota marginale con questi input:
- Il valore di ricerca è "inc" (G4)
- La tabella di ricerca è "tariffe" (B5: D11)
- Il numero della colonna è 3, Imposta cumulativa
- Il tipo di corrispondenza è 1 = corrispondenza approssimativa
VLOOKUP(inc,rates,3,1) // returns 4,543
Con un reddito imponibile di $ 50.000, CERCA.VERT, in modalità di corrispondenza approssimativa, corrisponde a 39.475 e restituisce 4.543, l'imposta totale fino a $ 39.475.
Il secondo CERCA.VERT calcola il reddito residuo da tassare:
(inc-VLOOKUP(inc,rates,1,1)) // returns 10,525
calcolato in questo modo:
(50.000-39.475) = 10.525
Infine, il terzo CERCA.VERT ottiene l'aliquota fiscale marginale (superiore):
VLOOKUP(inc,rates,2,1) // returns 22%
Questo viene moltiplicato per il reddito calcolato nel passaggio precedente. La formula completa si risolve in questo modo:
=VLOOKUP(inc,rates,3,1)+(inc-VLOOKUP(inc,rates,1,1))*VLOOKUP(inc,rates,2,1) =4,543+(10525)*22% =6,859
Tassi marginali ed effettivi
La cella G6 contiene il tasso marginale superiore, calcolato con CERCA.VERT:
=VLOOKUP(inc,rates,2,1) // returns 22%
L'aliquota fiscale effettiva in G7 è l'imposta totale divisa per il reddito imponibile:
=G5/inc // returns 13.7%
Nota: mi sono imbattuto in questa formula sul blog di Jeff Lenning all'Università di Excel. È un ottimo esempio di come VLOOKUP possa essere utilizzato in modalità di corrispondenza approssimativa e anche di come VLOOKUP possa essere utilizzato più volte nella stessa formula.
